# Maintainer: Allen Hoffmeyer <allen dot hoffmeyer at gmail dot com>
#               (adapted from work by Louis R. Marascio <lrm at fitnr dot com>)
# Contributor: trader <trader9 at gawab dot com>
# Contributor: masutu <masutu dot arch at googlemail dot com>

pkgname=quantlib
pkgver=1.8.r67.g6724b0b
pkgrel=1
pkgdesc="A free/open-source library for quantitative finance."
arch=('i686' 'x86_64')
url="http://quantlib.org"
license=('BSD')
options=()
depends=('boost-libs' 'sh')
makedepends=('make' 'boost' 'gcc')
source=('quantlib::git+https://github.com/thrasibule/QuantLib.git#branch=CDS')
md5sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --long --tags | sed 's/^QuantLib-v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$srcdir"/"$pkgname"/
  ./autogen.sh
  ./configure --prefix=/usr --enable-intraday --enable-openmp
  make
}

package() {
  cd "$srcdir"/"$pkgname"/
  make DESTDIR="$pkgdir/" install
  install -D -m644 LICENSE.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE.TXT"
}

# vim:set ts=2 sw=2 et: