# cython: boundscheck=False, cdivision=True
import numpy as np
cimport numpy as np
from libc.math cimport log, exp

DTYPE = np.float64
ctypedef np.float_t DTYPE_t

cdef DTYPE_t weight_success(int dist, int dt, DTYPE_t alpha,
                           DTYPE_t delta, DTYPE_t gamma):
    cdef DTYPE_t structural, temporal, result
    structural = delta ** dist
    temporal = exp(-alpha * dt) * (1 - exp(-alpha))
    result = structural * temporal
    return result


cdef DTYPE_t weight_failure(int dist, int dt, DTYPE_t alpha,
                               DTYPE_t delta, DTYPE_t gamma):
    cdef DTYPE_t structural, temporal, result
    structural = delta ** dist
    temporal = 1. - exp(-alpha * dt)
    result = 1. - structural * temporal
    return result


def ml(dict root_victims, dict victims, dict non_victims,
       DTYPE_t alpha, DTYPE_t delta, DTYPE_t gamma=10):
    cdef:
        int n_roots, n_victims, n_nodes, roots, i, dist, dt, t
        DTYPE_t beta, all_failures
        list parents, failures, successes
    n_roots, n_victims = len(root_victims), len(victims)
    n_nodes = n_victims + len(non_victims)
    cdef:
        np.ndarray[DTYPE_t] probs = np.zeros(n_victims, dtype=DTYPE)
        np.ndarray[DTYPE_t] probs_fail = np.zeros(n_victims, dtype=DTYPE)
        np.ndarray[DTYPE_t] probs_nv = np.zeros(len(non_victims), dtype=DTYPE)
    for i, parents in enumerate(victims.itervalues()):
        failures = [log(weight_failure(dist, dt, alpha, delta, gamma))
                           for (dist, dt) in parents]
        all_failures = sum(failures)
        successes = [log(weight_success(dist, dt, alpha, delta, gamma))
                           for (dist, dt) in parents]
        probs[i] = max(s - failures[i] for i, s in enumerate(successes))
        probs_fail[i] = all_failures

    for i, parents in enumerate(non_victims.itervalues()):
        failures = [log(weight_failure(dist, dt, alpha, delta, gamma))
                           for (dist, dt) in parents]
        probs_nv[i] = sum(failures)
    probs.sort()
    probs = probs[::-1]
    cdef:
        np.ndarray[DTYPE_t] cums = probs.cumsum()
    for i in xrange(n_victims - 1, 0, -1):
        roots = n_victims - 1 - i
        beta = 1. / (1. + exp(-probs[i]))
        if beta > float(roots) / float(n_nodes):
            break
    else:
        print "alpha: {0}, delta: {1}. Everyone is a root".format(alpha, delta)
        roots = n_victims
    beta = float(roots) / float(n_nodes)
    return (beta, roots,
            roots * log(beta) + (n_nodes - roots) * log(1 - beta) + cums[i]
            + probs_nv.sum()
            + probs_fail.sum())